FLOOR.MATH

FLOOR.MATH(number [,multiple] [,mode])

Returns the number rounded down (by default) to the nearest integer or multiple.

number	The number to be rounded.
multiple	(Optional) (significance) The multiple you want the number rounded to (1): (= 0) zero is returned (> 0) rounded down to an exact multiple (< 0) rounded down to an exact multiple (negative sign is ignored)
mode	(Optional) A logical value indicating whether to round negative numbers down or up: False (or 0) = Negative numbers are rounded down away from zero (default) True (<> 0) = Negative numbers are rounded up towards zero

REMARKS

* For an illustrated example refer to the Rounding Functions page.
* The "significance" argument has been changed to "multiple".
* Positive numbers are rounded down to the nearest integer.
* Negative numbers are rounded down (when "mode" = False) and rounded up (when "mode" = True).
* If "number" is an exact multiple of "multiple", there will be no rounding.
* If "multiple" is left blank, then 1 is used.
* If "mode" is left blank, then False is used.
* The "mode" argument only affects negative numbers.
* If any of the arguments are not numeric, then #VALUE! is returned.
* You can use the CEILING.MATH function to round up by default to a certain multiple.
* You can use the ROUND function to round to a certain number of decimal places or digits.
* You can use the ROUNDDOWN function to round towards zero to a certain number of decimal places or digits.
* You can use the ROUNDUP function to round away from zero to a certain number of decimal places or digits.
* You can use the MROUND function to round to a certain multiple.
* You can use the INT function to return a number rounded down to the nearest integer.
* You can use the EVEN function to return the number rounded to the nearest even integer.
* You can use the ODD function to return the number rounded to the nearest odd integer.
* You can use the TRUNC function to return the number with any decimal places removed.
* You can use the NOW function to return the serial number of the current system date and time.
* This function was added in Excel 2013 to replace the FLOOR and FLOOR.PRECISE functions.
* For the Microsoft documentation refer to support.microsoft.com

	A
1	=FLOOR.MATH(45, 50) = 0
2	=FLOOR.MATH(0.9) = 0
3	=FLOOR.MATH(1.1) = 1
4	=FLOOR.MATH(1.5) = 1
5	=FLOOR.MATH(-1.5) = -2
6	=FLOOR.MATH(1.1, 3) = 0
7	=FLOOR.MATH(3.1, 3) = 3
8	=FLOOR.MATH(3.1, -3) = 3
9	=FLOOR.MATH(-1.99, -1) = -2
10	=FLOOR.MATH(-1.99, 1, FALSE) = -2
11	=FLOOR.MATH(-1.99, 1, TRUE) = -1
12	=FLOOR.MATH(8.26, 0.05) = 8.25
13	=FLOOR.MATH(0.234, 0.01) = 0.23
14	=FLOOR.MATH(NOW(), "0:20") = 11:20:00 AM
15	=FLOOR.MATH("text") = #VALUE!

1 - What is 45 rounded down to a multiple of 50.
2 - What is 0.9 rounded down to a multiple of 1.
3 - What is 1.1 rounded down to a multiple of 1.
4 - What is 1.5 rounded down to a multiple of 1.
5 - What is -1.5 rounded down to a multiple of 1.
6 - What is 1.1 rounded down to a multiple of 3.
7 - What is 3.1 rounded down to a multiple of 3.
8 - What is 3.1 rounded down to a multiple of -3. The minus sign is ignored, so this is the same as a multiple of plus 3.
9 - What is -1.99 rounded down to a multiple of -1. The minus sign is ignored, so this is the same as a multiple of plus 1.
10 - What is -1.99 rounded down to a multiple of 1. When (mode = False) negative numbers are rounded down (away from zero).
11 - What is -1.99 rounded up to a multiple of 1. When (mode = True) negative numbers are rounded up (towards zero).
12 - What is 8.26 rounded down to a multiple of 0.05.
13 - What is 0.234 rounded down to a multiple of 0.01.
14 - What is the current time rounded down to the nearest 20 minutes.
15 - If any of the arguments are not numeric.