CEILING.MATH

CEILING.MATH(number [,multiple] [,mode])

Returns the number rounded up (by default) to the nearest integer or multiple.

number	The number to be rounded.
multiple	(Optional) (significance) The multiple you want the number rounded to (1): (= 0) zero is returned (> 0) rounded up to an exact multiple (< 0) rounded up to an exact multiple (negative sign is ignored)
mode	(Optional) A logical value indicating whether to round negative numbers up or down: False (or 0) = Negative numbers are rounded up towards zero (default) True (<> 0) = Negative numbers are rounded down away from zero

REMARKS

* For an illustrated example refer to the Rounding Functions page.
* The "significance" argument has been changed to "multiple".
* Positive numbers are rounded up to the nearest integer.
* Negative numbers are rounded up (when "mode" = False) and rounded down (when "mode" = True).
* If "number" is an exact multiple of "multiple", there will be no rounding.
* If "multiple" is left blank, then 1 is used.
* If "mode" is left blank, then False is used.
* The "mode" argument only affects negative numbers.
* If any of the arguments are not numeric, then #VALUE! is returned.
* You can use the FLOOR.MATH function to round down by default to a certain multiple.
* You can use the ROUND function to round to a certain number of decimal places or digits.
* You can use the ROUNDDOWN function to round towards zero to a certain number of decimal places or digits.
* You can use the ROUNDUP function to round away from zero to a certain number of decimal places or digits.
* You can use the MROUND function to round to a certain multiple.
* You can use the INT function to return a number rounded down to the nearest integer.
* You can use the EVEN function to return the number rounded to the nearest even integer.
* You can use the ODD function to return the number rounded to the nearest odd integer.
* You can use the TRUNC function to return the number with any decimal places removed.
* You can use the NOW function to return the serial number of the current system date and time.
* This function was added in Excel 2013 to replace the CEILING and CEILING.PRECISE functions.
* For the Microsoft documentation refer to support.microsoft.com

	A
1	=CEILING.MATH(15, 50) = 50
2	=CEILING.MATH(0.9) = 1
3	=CEILING.MATH(1.1) = 2
4	=CEILING.MATH(1.5) = 2
5	=CEILING.MATH(-1.5) = -1
6	=CEILING.MATH(1.1, 3) = 3
7	=CEILING.MATH(3.1, 3) = 6
8	=CEILING.MATH(3.1, -3) = 6
9	=CEILING.MATH(-1.99, -1) = -1
10	=CEILING.MATH(-1.99, 1, FALSE) = -1
11	=CEILING.MATH(-1.99, 1, TRUE) = -2
12	=CEILING.MATH(8.26, 0.05) = 8.30
13	=CEILING.MATH(0.234, 0.01) = 0.24
14	=CEILING.MATH(NOW(), "0:20") = 5:20:00 PM
15	=CEILING.MATH("text") = #VALUE!

1 - What is 15 rounded up to a multiple of 50.
2 - What is 0.9 rounded up to a multiple of 1.
3 - What is 1.1 rounded up to a multiple of 1.
4 - What is 1.5 rounded up to a multiple of 1.
5 - What is -1.5 rounded up to a multiple of 1.
6 - What is 1.1 rounded up to a multiple of 3.
7 - What is 3.1 rounded up to a multiple of 3.
8 - What is 3.1 rounded up to a multiple of -3. The minus sign is ignored, so this is the same as a multiple of plus 3.
9 - What is -1.99 rounded up to a multiple of -1. The minus sign is ignored, so this is the same as a multiple of plus 1.
10 - What is -1.99 rounded up to a multiple of 1. When (mode = False) negative numbers are rounded up (towards zero).
11 - What is -1.99 rounded down to a multiple of 1. When (mode = True) negative numbers are rounded down (away from zero).
12 - What is 8.26 rounded up to a multiple of 0.05.
13 - What is 0.234 rounded up to a multiple of 0.01.
14 - What is the current time rounded up to the nearest 20 minutes.
15 - If any of the arguments are not numeric.